Thiết bị cần nhớ cấu hình sau khi mất điện: tên và mật khẩu Wi-Fi, địa chỉ broker, ngưỡng cảnh báo, chu kỳ gửi, số giờ chạy máy. ESP32 không có EEPROM thật; thay vào đó là NVS (Non-Volatile Storage) – một vùng flash được quản lý theo kiểu khóa – giá trị, có cân bằng hao mòn. Trong Arduino, dùng qua thư viện Preferences.

Sau bài này bạn sẽ:
  • Đọc/ghi cấu hình bằng Preferences.
  • Thiết kế namespace, khóa, giá trị mặc định.
  • Ghi dữ liệu thay đổi thường xuyên mà không làm hỏng flash.

1. Cấu trúc NVS

Hình 1. NVS tổ chức dữ liệu theo namespace và cặp khóa – giá trị.
Hình 1. NVS tổ chức dữ liệu theo namespace và cặp khóa – giá trị.
Hàm ghiHàm đọcKiểu
putBool, putUChar, putInt, putUInt, putULong64getBool, getUChar, getInt, getUInt, getULong64Số nguyên, logic
putFloat, putDoublegetFloat, getDoubleSố thực
putStringgetStringChuỗi
putBytesgetBytes, getBytesLengthMảng byte, struct

2. Lưu và nạp cấu hình

#include <Preferences.h>

struct Config {
  String ssid, pass, mqttHost;
  uint32_t intervalSec;
  float threshold;
};

Preferences prefs;
Config cfg;

void loadConfig() {
  prefs.begin("cfg", true);                         // true = chỉ đọc
  cfg.ssid = prefs.getString("ssid", "");           // giá trị mặc định nếu chưa có
  cfg.pass = prefs.getString("pass", "");
  cfg.mqttHost = prefs.getString("mqtt", "192.168.1.10");
  cfg.intervalSec = prefs.getUInt("interval", 600);
  cfg.threshold = prefs.getFloat("thresh", 35.0f);
  prefs.end();
}

void saveConfig() {
  prefs.begin("cfg", false);                        // đọc – ghi
  prefs.putString("ssid", cfg.ssid);
  prefs.putString("pass", cfg.pass);
  prefs.putString("mqtt", cfg.mqttHost);
  prefs.putUInt("interval", cfg.intervalSec);
  prefs.putFloat("thresh", cfg.threshold);
  prefs.end();
}

void setup() {
  Serial.begin(115200);
  loadConfig();
  if (cfg.ssid.isEmpty()) {
    Serial.println("Chua cau hinh Wi-Fi -> vao che do AP cau hinh (bai #8)");
  }
  Serial.printf("Chu ky %u s, nguong %.1f C\n", cfg.intervalSec, cfg.threshold);
}

void loop() {}

Kết hợp với bài #8 và #10: trang cấu hình qua AP gọi saveConfig() rồi ESP.restart(). Thêm một lệnh "khôi phục cài đặt gốc" (giữ nút BOOT 5 giây) gọi prefs.clear() trên namespace.

3. Ghi dữ liệu thay đổi thường xuyên

Hình 2. Ước lượng tuổi thọ flash theo tần suất ghi: ghi mỗi giây làm mòn flash trong vài năm.
Hình 2. Ước lượng tuổi thọ flash theo tần suất ghi: ghi mỗi giây làm mòn flash trong vài năm.

Flash chỉ chịu được số lần xóa giới hạn (cỡ 100 000 lần mỗi sector). NVS rải các lần ghi ra nhiều trang nên bền hơn nhiều so với ghi cố định một chỗ, nhưng ghi mỗi giây vẫn có thể làm mòn vùng NVS mặc định chỉ trong khoảng một – hai năm (ước lượng, chưa tính chi phí quản lý).

  • Chỉ ghi khi giá trị thay đổi – Preferences không tự so sánh với giá trị cũ ở mọi phiên bản; tự kiểm tra trước khi put.
  • Bộ đếm giờ chạy: đếm trong RAM, ghi NVS mỗi 10–60 phút và khi phát hiện sắp mất điện (nếu có mạch báo).
  • Dữ liệu log lớn (hàng nghìn mẫu) dùng LittleFS hoặc thẻ SD, không dùng NVS.
  • Muốn bền hơn: tạo phân vùng NVS riêng lớn hơn trong bảng phân vùng tùy chỉnh.

4. NVS, LittleFS hay EEPROM?

NVS / PreferencesLittleFSEEPROM (giả lập)
Phù hợpCấu hình nhỏ, bộ đếmFile: HTML, JSON lớn, logCode cũ chuyển từ Arduino AVR
Cân bằng hao mònCóCóKém (cài trên NVS, ghi cả khối)
Cách dùngKhóa – giá trịĐường dẫn fileĐịa chỉ byte, cần commit()

5. Lỗi thường gặp

  • Tên khóa hoặc namespace dài hơn 15 ký tự → ghi/đọc thất bại không rõ ràng (log báo lỗi KEY_TOO_LONG).
  • Quên prefs.end() hoặc mở cùng namespace ở hai nơi.
  • Đọc bằng kiểu khác với kiểu đã ghi (ghi putInt, đọc getUInt) → trả về giá trị mặc định.
  • Lưu mật khẩu dạng rõ: NVS có thể đọc ra khi có thiết bị trong tay; sản phẩm thương mại nên bật mã hóa flash/NVS.

Tài liệu tham khảo