Servo RC (SG90, MG90S, MG996R…) là cơ cấu chấp hành dễ dùng nhất: trong vỏ có động cơ DC, hộp số, biến trở đo vị trí và mạch điều khiển vòng kín. Arduino chỉ cần gửi một xung báo "góc mong muốn", servo tự quay tới và giữ ở đó. Ứng dụng: tay máy mini, cửa chắn, van mô hình, xoay camera.

1. Tín hiệu điều khiển servo

Hình 1. Ba vị trí 0°, 90°, 180° tương ứng ba độ rộng xung trong chu kỳ 20 ms.
Hình 1. Ba vị trí 0°, 90°, 180° tương ứng ba độ rộng xung trong chu kỳ 20 ms.

Servo nhận một xung mỗi 20 ms (50 Hz). Độ rộng xung quy định góc: khoảng 1,5 ms là giữa hành trình (90°), ngắn hơn quay về một phía, dài hơn quay về phía kia. Đây không phải PWM thay đổi điện áp trung bình như bài #4 – servo đo chính độ rộng xung.

2. Đấu nối an toàn

Hình 2. Servo lấy nguồn riêng, chỉ dây tín hiệu nối Arduino, GND chung.
Hình 2. Servo lấy nguồn riêng, chỉ dây tín hiệu nối Arduino, GND chung.

Servo có 3 dây: cam/vàng = tín hiệu, đỏ = nguồn (+5 V), nâu/đen = GND.

Không cấp nguồn servo từ chân 5V của Arduino (trừ 1 servo SG90 không tải để thử). Khi khởi động hoặc bị cản, MG996R có thể kéo 1–2 A, làm sụt áp, Arduino khởi động lại liên tục hoặc cổng USB máy tính tự ngắt. Dùng nguồn 5–6 V riêng, GND nối chung với Arduino, thêm tụ 470–1000 µF sát chân nguồn servo.

3. Thư viện Servo và hiệu chỉnh

Hình 3. Quan hệ độ rộng xung – góc; mỗi servo cần đo lại giới hạn thực tế.
Hình 3. Quan hệ độ rộng xung – góc; mỗi servo cần đo lại giới hạn thực tế.

Thư viện Servo mặc định ánh xạ 0–180° thành 544–2400 µs. Nhiều servo không quay đủ 180°, hoặc tì vào giới hạn cơ khí ở hai đầu (kêu rè, nóng, tốn dòng). Cách làm đúng: dùng writeMicroseconds() tăng/giảm dần để tìm giới hạn thực tế của servo, rồi truyền vào attach(pin, min, max).

#include <Servo.h>

Servo sv;
const int PULSE_MIN = 600;    // µs – đo thực tế cho servo của bạn
const int PULSE_MAX = 2350;

int current = 90, target = 90;
unsigned long tStep = 0;
const unsigned long STEP_MS = 15;   // 1 độ / 15 ms ≈ 67 °/s

void setup() {
  sv.attach(9, PULSE_MIN, PULSE_MAX);
  sv.write(current);
}

void loop() {
  // biến trở ở A0 đặt góc đích
  target = map(analogRead(A0), 0, 1023, 0, 180);

  // tiến dần tới đích, không chặn chương trình
  if (millis() - tStep >= STEP_MS && current != target) {
    tStep = millis();
    current += (target > current) ? 1 : -1;
    sv.write(current);
  }
}

Giới hạn tốc độ quay giúp chuyển động êm, giảm dòng đỉnh và giảm rung cho cơ cấu – đặc biệt quan trọng với tay máy (xem dự án #45 cánh tay robot mini).

Trên Uno, thư viện Servo dùng Timer1 nên analogWrite() ở chân 9 và 10 không còn hoạt động. Nếu cần nhiều servo (tối đa 12 trên Uno) hoặc cần giữ PWM, dùng module PCA9685 điều khiển 16 servo qua I²C.

4. Servo 360° (quay liên tục)

Servo "continuous rotation" không có biến trở phản hồi vị trí: xung 1,5 ms = đứng yên, lệch về hai phía = quay thuận/nghịch với tốc độ tăng dần. Không điều khiển được góc – muốn quay chính xác góc cần động cơ bước hoặc động cơ có encoder.

5. Lỗi thường gặp

  • Servo rung giật liên tục: nguồn yếu, thiếu GND chung, hoặc giá trị biến trở nhảy – lọc giá trị analog (bài #5).
  • Arduino reset khi servo chạy: dùng chung nguồn với Arduino.
  • Servo kêu và nóng khi đứng yên: đang ép vào giới hạn cơ khí – thu hẹp PULSE_MIN/MAX.

6. Bài tập

  1. Tìm giới hạn xung thực tế của servo bằng lệnh Serial US 1500 (kết hợp bài #6).
  2. Làm thanh chắn tự động: cảm biến HC-SR04 (bài #14) phát hiện xe < 20 cm thì mở 90°, sau 3 s đóng lại.
  3. Điều khiển 2 servo (pan–tilt) bằng joystick analog.

Bài tiếp theo: #12 – Động cơ DC với L298N.

Tài liệu tham khảo