HC-05 là module Bluetooth Classic giá rẻ hoạt động như một "dây Serial không dây": điện thoại gửi chữ, Arduino nhận qua UART như ở bài #6. Chỉ vài dòng code là bạn điều khiển được đèn, relay, xe robot từ điện thoại Android.
1. Đấu nối

Module HC-05 (bản có đế 6 chân) nhận nguồn 3,6–6 V nhưng mức logic là 3,3 V. Chân TXD của module (3,3 V) nối thẳng vào Arduino được vì 3,3 V vẫn được hiểu là HIGH. Chiều ngược lại, TX của Arduino ra 5 V nên cần phân áp 1 kΩ/2 kΩ trước khi vào RXD.
Dùng SoftwareSerial ở D10/D11 để giữ cổng USB cho Serial Monitor.
2. Kiến trúc

Khi ghép đôi, điện thoại thấy HC-05 như một cổng COM ảo theo chuẩn SPP (Serial Port Profile). Trên Android, dùng một ứng dụng "Bluetooth terminal" bất kỳ hỗ trợ SPP để gửi lệnh dạng chữ.
3. Cấu hình bằng lệnh AT
Để vào chế độ AT: giữ nút trên module (hoặc nối chân EN/KEY lên 3,3 V) trong lúc cấp nguồn – LED nháy chậm ~2 giây/lần. Ở chế độ này module giao tiếp ở 38400 baud. Nạp chương trình "cầu nối" sau, mở Serial Monitor chọn "Both NL & CR":
#include <SoftwareSerial.h>
SoftwareSerial bt(10, 11); // RX, TX
void setup() {
Serial.begin(9600);
bt.begin(38400); // tốc độ chế độ AT của HC-05
}
void loop() {
if (Serial.available()) bt.write(Serial.read());
if (bt.available()) Serial.write(bt.read());
}
| Lệnh | Ý nghĩa |
|---|---|
AT | Kiểm tra – trả về OK |
AT+NAME=TechVis-Lab | Đổi tên hiển thị khi dò thiết bị |
AT+PSWD="2468" | Đổi mã ghép đôi (một số firmware dùng AT+PSWD=2468 không có ngoặc kép) |
AT+UART=9600,0,0 | Tốc độ ở chế độ dữ liệu: 9600 baud, 1 stop bit, không parity |
AT+ROLE=0 | 0 = slave (chờ điện thoại kết nối), 1 = master |
Mật khẩu mặc định thường là 1234 hoặc 0000. Sau khi cấu hình, cấp nguồn lại bình thường (không giữ nút) để về chế độ dữ liệu.
4. Chương trình điều khiển
#include <SoftwareSerial.h>
SoftwareSerial bt(10, 11);
const byte RELAY = 7, LED = 13;
char buf[24]; byte len = 0;
void reply(const __FlashStringHelper *msg) { bt.println(msg); Serial.println(msg); }
void handle(char *cmd) {
if (!strcmp(cmd, "DEN BAT")) { digitalWrite(LED, HIGH); reply(F("OK den bat")); }
else if (!strcmp(cmd, "DEN TAT")) { digitalWrite(LED, LOW); reply(F("OK den tat")); }
else if (!strcmp(cmd, "RELAY BAT")){ digitalWrite(RELAY, HIGH); reply(F("OK relay bat")); }
else if (!strcmp(cmd, "RELAY TAT")){ digitalWrite(RELAY, LOW); reply(F("OK relay tat")); }
else reply(F("Lenh: DEN BAT|DEN TAT|RELAY BAT|RELAY TAT"));
}
void setup() {
pinMode(RELAY, OUTPUT); pinMode(LED, OUTPUT);
Serial.begin(9600);
bt.begin(9600); // tốc độ đã đặt bằng AT+UART
}
void loop() {
while (bt.available()) {
char c = toupper(bt.read());
if (c == '\r') continue;
if (c == '\n') { buf[len] = 0; if (len) handle(buf); len = 0; }
else if (len < sizeof(buf) - 1) buf[len++] = c;
}
}
5. Lỗi thường gặp
- Không vào được chế độ AT: phải giữ nút trước khi cấp nguồn; baud phải là 38400.
- Kết nối được nhưng không nhận lệnh: sai baud ở chế độ dữ liệu, đấu TX/RX chưa chéo, ứng dụng không gửi ký tự xuống dòng.
- Module reset khi relay đóng: nguồn yếu, nhiễu từ cuộn relay (xem bài #19).
6. Bài tập
- Thêm lệnh
PWM nchỉnh độ sáng LED và lệnhNHIETDOtrả về giá trị DHT22 (bài #13). - Điều khiển xe 2 động cơ (bài #12) bằng các lệnh T (tiến), L (lùi), TR, PH, D (dừng), có tự dừng khi mất lệnh.
- Lưu trạng thái relay vào EEPROM (bài #15) để giữ nguyên sau khi mất điện.
Bài tiếp theo: #17 – Arduino + ESP8266 đưa dữ liệu lên mạng.